Shader入门精要（七）基础纹理

fasty2022-12-262025-12-11

Unity Shader 第七章基础纹理

纹理——使用一张图片来控制模型的外观，使用纹理映射技术把一张图黏在模型表面，逐纹素地控制模型的颜色。

通常使用纹理映射坐标对应纹理中的2D坐标，这被称为是UV坐标。

顶点UV坐标的范围通常被归一到[0,1]范围内。

DirectX 中原点位于左上角，OpenGL中原点位于左下角。

$\color{red}{Unity 使用的是OpenGL的坐标，即原点位于左下角}$

纹理采样

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Book/SingleTexture"
{
    Properties
    {
        _Color("Color Tint",Color)=(1,1,1,1)
        _MainTex ("Texture", 2D) = "white" {}
        //        反射
        _Specular("Specular",Color)=(1,1,1,1)
        //        高光
        _Gloss("Gloss",Range(8.0,256))=20
    }

    SubShader
    {
        Tags
        {
            "RenderType"="Opaque"
            "LightMode"="ForwardBase"
        }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            // make fog work
            #pragma multi_compile_fog

            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            // 声明对应变量
            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Specular;
            float _Gloss;

            // 输入
            struct a2v
            {
                float4 vertex: POSITION;
                float3 normal: NORMAL;
                float4 texcoord: TEXCOORD0;
            };

            struct v2f
            {
                float4 pos: SV_POSITION;
                float3 worldNormal: TEXCOORD0;
                float3 worldPos: TEXCOORD1;
                float2 uv: TEXCOORD2;
            };

            // 进行顶点着色器
            v2f vert(a2v v)
            {
                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

                // 计算Thing And Offset
                o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
                // 可使用Unity内置宏
                // o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                return o;
            }

            // 进行片元着色器
            fixed4 frag(v2f i): SV_Target
            {
                // 光线方向
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                // 纹理采样
                fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
                // 环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                // 漫反射- 半兰伯特模型
                fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));

                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));

                fixed3 halfDir = normalize(worldLightDir + viewDir);
                // 高光反射
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);

                return fixed4(ambient + diffuse + specular, 1.0);
            }
            ENDCG
        }

    }
    
    Fallback "Specular"

}

值得注意的是：

如果导入的纹理大小超过了Max Texture Size中的设置值，那么Unity将会把该纹理缩放为这个最大分辨率。理想情况下，导入的纹理可以是非正方形的，但长宽的大小应该是2的幂，例如2、4、8、16、32、64等。如果使用了非2的幂大小（Non Power of Two, NPOT）的纹理，那么这些纹理往往会占用更多的内存空间，而且GPU读取该纹理的速度也会有所下降。有一些平台甚至不支持这种NPOT纹理，这时Unity在内部会把它缩放成最近的2的幂大小。出于性能和空间的考虑，我们应该尽量使用2的幂大小的纹理。

凹凸映射

纹理的一种应用是凹凸映射（使用一张纹理来修改模型表面的法线，以便为模型提供更多的细节。）——++ 法线贴图 ++。

有以下两种映射方式【高度纹理，法线纹理】：

高度纹理

存储颜色强度值来表示海拔高度，颜色越深表面越向外凸起，颜色越钱表面越向内凹陷。

优点：直观明显

缺点：计算复杂，不能实时计算得到表面法线，消耗性能。

法线纹理

存储表面法线方向，范围值为[-1,1],而像素分量范围为[0,1]，需要进行映射。

在对法线纹理进行采样后，还需要对结果进行一次反映射得到法线方向：

normal=pixel*2-1

根据使用的坐标系分为：

模型空间的法线纹理

因为法线方向各不相同，在对应到贴图上是会呈现出不同的颜色，不同的颜色就对应不同的法线方向。——直观
切线空间的法线纹理

切线空间下的法线则呈现浅蓝色